RDOSocialConnectors object

 

RDOSocialConnectors collection represents Social Connectors (such as Facebook or LinkedIn) present in a particular Outlook profile.

 

This object accesses data outside of Microsoft Outlook. Please make sure your usage satisfies the licensing terms of the particular Social Provider (Facebook, LinkedIn, etc.)

 

Returned by:

RDOSession.ScocialConnectors

 

The example below update all contacts in the currently selected folder to include the contact's picture, title, name, etc.

set Session = CreateObject("Redemption.RDOSession")
Session.MAPIOBJECT = Application.Session.MAPIOBJECT
set SocialConnector = Session.SocialConnectors.Item("Linkedin")
set Folder = Session.GetFolderFromID(Application.ActiveExplorer.CurrentFolder.EntryID)
if not (Folder Is Nothing) Then
  for each item in Folder.Items
    if TypeName(item) = "RDOContactItem" Then 'we don't care about distribution lists

       'build a list of email addresses for the current contact
        strEmails = item.Email1Address
        if item.Email2Address <> "" Then
          if strEmails <> "" Then strEmails = strEmails & ";"
          strEmails = strEmails & item.Email2Address
        End If
        if item.Email3Address <> "" Then
          if strEmails <> "" Then strEmails = strEmails & ";"
          strEmails = strEmails & item.Email3Address
        End If
        if strEmails <> "" Then
          Debug.Print "Searching for " & strEmails
          set persons = SocialConnector.FindPerson(strEmails)
          for each person in persons
            'properties
            if item.JobTitle = "" Then item.JobTitle = person.Title
            if item.Companies = "" Then item.Title = person.Company
            if item.LastName = "" Then item.LastName = person.LastName
            if item.FirstName = "" Then item.FirstName = person.FirstName
            if item.WebPage = "" Then item.WebPage = person.WebProfilePage
            'picture
            if not item.HasPicture Then
              set pict = person.Picture
              if Not (pict Is Nothing) Then
                item.AddPicture pict.AsFile
              End If
            End If
            if Item.Modified Then item.Save
          next
        End If
    End If
  next
End If

 

Properties

Methods

 

 

Derived from: IDispatch

Properties
Count
 integer, read-only. Returns he number of social connectors in the collection.
  

Methods
Item(Index)
 Returns RDOSocialConnector object corresponding to the given index (1 through Count).